Ficheiro:Lagrangian points equipotential.gif

O conteúdo da página não é suportado noutras línguas.
Origem: Wikipédia, a enciclopédia livre.

Lagrangian_points_equipotential.gif ‎(512 × 384 píxeis, tamanho: 2 MB, tipo MIME: image/gif, cíclico, 72 quadros, 7,2 s)

Descrição do ficheiro

Descrição
English: Animation showing the relationship between the five Lagrangian points (red) of a planet (blue) orbiting a star (yellow), and the gravitational potential in the plane containing the orbit (grey surface with purple contours of equal potential). The potential was computed in POV-Ray using

for q = 0.1 and z = 0.[1]
Origem Obra do próprio
Autor cmglee
Outras versões
Lagrangian points equipotential.png
Lagrangian points equipotential.jpg
Roche potential.stl

POV-Ray source code

Lagrangian_points_equipotential.pov Lagrangian_points_equipotential.ini 
#declare rotation = clock;
// #declare rotation = -28;
#declare bounding_radius = 8;
#declare q = 0.1;
#declare q_plus_1 = q + 1;
#declare q_divide_q_plus_1 = q / q_plus_1;
#declare two_divide_q_plus_1 = 2 / q_plus_1;

union {
 isosurface {
  function {
   y + (pow(x-q_divide_q_plus_1,2) + z*z + two_divide_q_plus_1 * (q / sqrt((x-1)*(x-1)+z*z) + 1 / sqrt(x*x + z*z)))
  } 
  accuracy     0.001
  max_gradient 200 // increase to reduce artifact in funnel
  contained_by {sphere{0,bounding_radius}} open
  pigment {
   gradient <0,1,0>
   color_map {                                               [0.01 color rgb <0.5,0,0.75>][0.02 color rgb 1]
              [0.18 color rgb 1][0.19 color rgb <0.75,0.5,1>][0.21 color rgb <0.75,0.5,1>][0.22 color rgb 1]
              [0.38 color rgb 1][0.39 color rgb <0.75,0.5,1>][0.41 color rgb <0.75,0.5,1>][0.42 color rgb 1]
              [0.58 color rgb 1][0.59 color rgb <0.75,0.5,1>][0.61 color rgb <0.75,0.5,1>][0.62 color rgb 1]
              [0.78 color rgb 1][0.79 color rgb <0.75,0.5,1>][0.81 color rgb <0.75,0.5,1>][0.82 color rgb 1]
              [0.98 color rgb 1][0.99 color rgb <0.75,0.5,1>]                                               }
   scale 0.5
   translate <0,0.03,0>
  }
  scale     <1,0.5,1>
  translate <0,1.42,0>
 }
 union {
  sphere {0,0.2          pigment {rgbt <1,1,0,0.5>}   interior {ior 1} finish {specular 1 roughness 0.1} }
  sphere {<1,0,0>,0.1    pigment {rgbt <0,0.5,1,0.5>} interior {ior 1} finish {specular 1 roughness 0.1} }
  sphere {<q/2,0,0>,0.05 pigment {rgb  <0.5,0,0>} }
  union {
   torus    {1-q/2,0.02 translate <q/2,0,0>}
   cylinder {<-0.95,0,0>,<1.35,0,0>,0.02}
   cylinder {<q/2,0,0>,<0.5,0,0.866>,0.02}
   cylinder {<q/2,0,0>,<0.5,0,-0.866>,0.02}
   pigment  {rgb <0,0.75,0>}
  }
  union {
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L1" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <0.72,0,0> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L2" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <1.35,0,0> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L3" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <-0.95,0,0> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L4" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <0.5,0,0.866> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L5" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <0.5,0,-0.866> }
   pigment {rgb <1,0,0>}
  }
 }
 translate <-q/2,-0.14,0>
 rotate    <0,-rotation,0>
}
sky_sphere {pigment {rgb 1}}
light_source {<0,1,0>    color rgb 0.5 parallel point_at 0}
light_source {<0,10,-10> color rgb 1   shadowless}
camera {orthographic location <0.05,7.8,-10> look_at <0.05,-0.1,0> angle 13.8}

Antialias=off
Antialias_Threshold=0.01
Antialias_Depth=2

Input_File_Name="Lagrangian_points_equipotential.pov"

Initial_Frame=0
Final_Frame=71
Initial_Clock=0
Final_Clock=360

Cyclic_Animation=on
Pause_when_Done=off
  1. ↑ ZF Seidov, "The Roche Problem: Some Analytics", The Astrophysical Journal, 603:283-284, 2004 March 1

Licenciamento

Eu, titular dos direitos de autor desta obra, publico-a com as seguintes licenças:
w:pt:Creative Commons
atribuição partilha nos termos da mesma licença
A utilização deste ficheiro é regulada nos termos da licença Creative Commons - Atribuição-CompartilhaIgual 3.0 Não Adaptada.
Pode:
  • partilhar – copiar, distribuir e transmitir a obra
  • recombinar – criar obras derivadas
De acordo com as seguintes condições:
  • atribuição – Tem de fazer a devida atribuição da autoria, fornecer uma hiperligação para a licença e indicar se foram feitas alterações. Pode fazê-lo de qualquer forma razoável, mas não de forma a sugerir que o licenciador o apoia ou subscreve o seu uso da obra.
  • partilha nos termos da mesma licença – Se remisturar, transformar ou ampliar o conteúdo, tem de distribuir as suas contribuições com a mesma licença ou uma licença compatível com a original.
GNU head É concedida permissão para copiar, distribuir e/ou modificar este documento nos termos da Licença de Documentação Livre GNU, versão 1.2 ou qualquer versão posterior publicada pela Free Software Foundation; sem Secções Invariantes, sem textos de Capa e sem textos de Contra-Capa. É incluída uma cópia da licença na secção intitulada GNU Free Documentation License.
Pode escolher a licença que quiser.

Legendas

Adicione uma explicação de uma linha do que este ficheiro representa

Elementos retratados neste ficheiro

retrata

Histórico do ficheiro

Clique uma data e hora para ver o ficheiro tal como ele se encontrava nessa altura.

Data e horaMiniaturaDimensõesUtilizadorComentário
atual23h57min de 22 de outubro de 2021Miniatura da versão das 23h57min de 22 de outubro de 2021512 × 384 (2 MB)CmgleeIncrease resolution and framerate, rotate around barycentre, reframe image and make bodies transparent
10h35min de 16 de fevereiro de 2013Miniatura da versão das 10h35min de 16 de fevereiro de 2013256 × 192 (709 kB)CmgleeUse 6-bit GIFs.
10h06min de 16 de fevereiro de 2013Miniatura da versão das 10h06min de 16 de fevereiro de 2013256 × 192 (574 kB)CmgleeFix shifting background colour.
09h51min de 16 de fevereiro de 2013Miniatura da versão das 09h51min de 16 de fevereiro de 2013256 × 192 (574 kB)CmgleeOrbit around barycentre instead of Sun, darken every fifth contour and double number of frames.
23h41min de 15 de fevereiro de 2013Miniatura da versão das 23h41min de 15 de fevereiro de 2013256 × 192 (354 kB)Cmglee{{Information |Description ={{en|1=Animation showing the relationship between the five Lagrangian points (red) of a planet (blue) orbiting a star (yellow), and the gravitational potential in the plane containing the orbit (grey surface with purple c...

Não há nenhuma página que use este ficheiro.

Utilização global do ficheiro

As seguintes wikis usam este ficheiro:

Metadados

Este ficheiro contém informação adicional, provavelmente adicionada a partir da câmara digital ou scanner utilizada para criar ou digitalizar a imagem. Caso o ficheiro tenha sido modificado a partir do seu estado original, alguns detalhes poderão não refletir completamente as mudanças efetuadas.

Obtida de "https://pt.wikipedia.org/wiki/Ficheiro:Lagrangian_points_equipotential.gif"