Usuária:GiFontenelle/Testes/Portal NeuroMat/4
Aspeto
Página inicial | Projetos de difusão | Eventos | Pesquisa | Participantes |
Esta página concentra dados sobre as publicações do Centro de Pesquisa, Inovação e Difusão em Neuromatemática que estão disponíveis no Wikidata.
Publicações |
Datas e sobrenomes dos autores em publicações do NeuroMat
[editar | editar código-fonte]Query com as datas e sobrenomes dos autores em publicações do NeuroMat
O código abaixo gera um grafo com datas e sobrenomes dos autores em publicações do NeuroMat.
#defaultView:Graph
SELECT DISTINCT ?Artigo (?Nome_do_artigo AS ?ArtigoLabel) ?rgb ?Artigo_citado WITH {
SELECT DISTINCT ?Artigo ?Autor ?Ordem WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?Artigo wdt:P361 wd:Q18477654.
?Artigo p:P50 ?Autor_.
?Autor_ ps:P50 ?Autor.
?Autor_ pq:P1545 ?Ordem_.
BIND(xsd:integer(?Ordem_) AS ?Ordem)
}
} AS %artigos
WITH {
SELECT DISTINCT ?Artigo (MAX(?Ordem) AS ?Ordem_max) (MIN(?Ordem) AS ?Ordem_min) WHERE {
INCLUDE %artigos.
} GROUP BY ?Artigo
} AS %ordem
WITH {
SELECT DISTINCT ?Artigo ?Autor1_nome ?Autor2_nome ?Ordem_max WHERE {
INCLUDE %ordem.
BIND(STR(?Ordem_max) AS ?O_max)
BIND(STR(?Ordem_min) AS ?O_min)
?Artigo p:P50 ?Autor_p1.
?Artigo p:P50 ?Autor_p2.
?Autor_p1 ps:P50 ?Autor1.
?Autor_p2 ps:P50 ?Autor2.
?Autor_p1 pq:P1545 ?O_min.
?Autor_p2 pq:P1545 ?O_max.
?Autor1 rdfs:label ?Autor_name_1. FILTER(LANG(?Autor_name_1)="pt-br")
BIND(REPLACE(STR(?Autor_name_1),REPLACE(str(?Autor_name_1),'[^ ]*$',''),'') AS ?Autor1_nome)
?Autor2 rdfs:label ?Autor_name_2. FILTER(LANG(?Autor_name_2)="pt-br")
BIND(REPLACE(STR(?Autor_name_2),REPLACE(str(?Autor_name_2),'[^ ]*$',''),'') AS ?Autor2_nome)
}
} AS %autores
WHERE {
INCLUDE %autores.
OPTIONAL {?Artigo wdt:P577 ?data_aux.
BIND(YEAR(?data_aux) AS ?data_)}
BIND(IF(BOUND(?data_),STR(?data_),"?") AS ?data)
BIND(IF(?Ordem_max=1,
CONCAT(?Autor1_nome, ", ", ?data),
IF(?Ordem_max=2,
CONCAT(?Autor1_nome, ", ", ?Autor2_nome, ", ", ?data),
CONCAT(?Autor1_nome, " et al, ", ?data))) AS ?Nome_do_artigo)
OPTIONAL{?Artigo wdt:P2860 ?Artigo_citado.
?Artigo_citado wdt:P361 wd:Q18477654.}
BIND(IF(?Artigo=wd:Q56592766,"053789",
IF(?Artigo_citado=wd:Q56592766,"00a5cf",
"ffffff")) AS ?rgb)
}
Número de artigos do NeuroMat por autor
[editar | editar código-fonte]Query com o número de artigos do NeuroMat por autor
O código abaixo gera um histograma do número de artigos do NeuroMat por autor.
#defaultView:BarChart
SELECT ?Nome_do_autor ?Nome_do_autorLabel (COUNT(distinct(?item)) AS ?Número_de_artigos) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P361 wd:Q18477654.
OPTIONAL { ?item wdt:P50 ?Nome_do_autor. }
} group by ?Nome_do_autor ?Nome_do_autorLabel
Distribuição de autores em publicações do NeuroMat por gênero
[editar | editar código-fonte]Query com a distribuição de autores em publicações do NeuroMat por gênero
O código abaixo gera um gráfico de barras com a distribuição de autores em publicações do NeuroMat por gênero.
#defaultView:BarChart
SELECT (SAMPLE(?Gênero) AS ?Gênero) (COUNT(DISTINCT(?Autores)) AS ?Número_de_autores) (SAMPLE(?Nome_autores) AS ?Autores) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?Obra wdt:P361 wd:Q18477654.
?Obra wdt:P50 ?Autores.
?Autores wdt:P21 ?Gênero_aux.
?Gênero_aux rdfs:label ?Gênero. FILTER(LANG(?Gênero)="pt-br")
?Autores rdfs:label ?Nome_autores. FILTER(LANG(?Nome_autores)="pt-br")
} GROUP BY ?Nome_autores
ORDER BY ?Gênero ?Nome_autores
Número de publicações do NeuroMat por gênero dos autores
[editar | editar código-fonte]Query com o número de publicações do NeuroMat por gênero dos autores
O código abaixo gera um gráfico de barras com número de publicações do NeuroMat por gênero dos autores.
#defaultView:BarChart
SELECT ?Gênero ?GêneroLabel (COUNT(distinct(?item)) AS ?Número_de_artigos) WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P361 wd:Q18477654.
OPTIONAL { ?item wdt:P50 ?Nome_do_autor. }
OPTIONAL { ?Nome_do_autor wdt:P21 ?Gênero. }
} group by ?Gênero ?GêneroLabel
Perfis de entidades relacionadas ao NeuroMat no Scholia
[editar | editar código-fonte]Query com os perfis de entidades relacionadas ao NeuroMat no Scholia
O código abaixo gera uma tabela com a relação de perfis de entidades relacionadas ao NeuroMat no Scholia.
SELECT DISTINCT ?Wikidata_ID ?Nome ?Tipo ?Perfil_no_Scholia WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
{
BIND(wd:Q18477654 AS ?Wikidata_ID)
wd:Q18477654 rdfs:label ?Nome_revista.
FILTER(LANG(?Nome_revista)="pt-br")
BIND(STR(?Nome_revista) AS ?Nome)
BIND("Instituição" AS ?Tipo)
BIND(SUBSTR(STR(?Wikidata_ID),32) AS ?qid)
BIND(IRI(CONCAT("https://tools.wmflabs.org/scholia/venue/", ?qid)) AS ?Perfil_no_Scholia)
}
UNION
{
?Artigos wdt:P361 wd:Q18477654.
?Artigos rdfs:label ?Nome_artigo.
FILTER(LANG(?Nome_artigo)="pt-br")
BIND(SUBSTR(STR(?Artigos),32) AS ?qid)
BIND(IRI(CONCAT("https://tools.wmflabs.org/scholia/work/", ?qid)) AS ?Perfil_no_Scholia)
BIND("Artigo" AS ?Tipo)
BIND(STR(?Nome_artigo) AS ?Nome)
BIND(?Artigos AS ?Wikidata_ID)
}
UNION
{
?Artigos2 wdt:P361 wd:Q18477654.
?Artigos2 wdt:P50 ?Autores_aux.
?Autores_aux rdfs:label ?Autores.
FILTER(LANG(?Autores)="pt-br")
BIND(SUBSTR(STR(?Autores_aux),32) AS ?qid)
BIND(IRI(CONCAT("https://tools.wmflabs.org/scholia/author/", ?qid)) AS ?Perfil_no_Scholia)
BIND("Autor(a)" AS ?Tipo)
BIND(STR(?Autores) AS ?Nome)
BIND(?Autores_aux AS ?Wikidata_ID)
}
}